TinTin++ Mud Client Scripts  
space
space
This script creates a list of mobs you've killed, as well as how many times you've killed them, average experience received, and total experience received.

This script is written for v2.01.97 and higher

space
#EVENT {SESSION CONNECTED}
{
     #list gains clear
}

#ACTION {%1 is DEAD!!$}
{
     #variable mob %1
}

#ACTION {You are awarded %d experience points for the battle.}
{
     #math {gains[$mob][exp]} {$gains[$mob][exp] + %1};
     #math {gains[$mob][cnt]} {$gains[$mob][cnt] + 1}
}

#ALIAS {rip}
{
     #showme {      Average Xp       Total Xp     #   Death List, R.I.P.};
     #showme {----------------------------------------------------------};
     #unvariable {gains[final]};
     #foreach {$gains[]} {mob}
     {
          #echo {  %+14G %+14G %+5G   %s}{$gains[$mob][exp] / $gains[$mob][cnt]}{$gains[$mob][exp]}{$gains[$mob][cnt]}{$mob};
          #math gains[final][exp] $gains[final][exp] + $gains[$mob][exp];
          #math gains[final][cnt] $gains[final][cnt] + $gains[$mob][cnt]
     };
     #showme {----------------------------------------------------------};
     #math tmp {$gains[final][exp] / $gains[final][cnt]};
     #echo {  %+14G %+14G %+5G}{$tmp}{$gains[final][exp]}{$gains[final][cnt]}
}

#ALIAS {example}
{
     #nop The output will look as following:;
     #nop |------------------------------------------------;
     #nop |     Average Xp       Total Xp     #   R.I.P.   ;
     #nop |------------------------------------------------;
     #nop |         28,860        230,881     8   Adina    ;
     #nop |         53,391        320,349     6   Bobby    ;
     #nop |         52,631        157,894     3   Bubba    ;
     #nop |         55,880        167,642     3   Cindy    ;
     #nop |         45,312        271,873     6   Frank    ;
     #nop |         60,123        240,495     4   Heidi    ;
     #nop |         40,269        322,158     8   Jimmy    ;
     #nop |         41,423        207,115     5   Julia    ;
     #nop |         66,794        267,178     4   Petra    ;
     #nop |         70,617        211,853     3   Timmy    ;
     #nop |------------------------------------------------;
     #nop |         47,948      2,397,438    50            
}