#EVENT {SESSION CONNECTED}
{
    #variable REPORTABLE_VARIABLES {ROOM};
    #nop Turn telnet debug on if there are problems.;
    #config {debug telnet} {off};
    #split 16 1;
    #map create 100000;
    #map flag nofollow;
    #map flag vtmap;
    #map flag static;
    #map read msdp.map
}

#EVENT {SESSION DISCONNECTED}
{
    #map write msdp.map
}

#EVENT {IAC WILL MSDP}
{
    #line oneshot #format IAC_DO_MSDP {%a%a%a} {255} {253} {69};
    #send {$IAC_DO_MSDP\};
    msdp_report
}

#EVENT {IAC SB MSDP}
{
    #nop Save all variables with an MSDP_ prefix.;
    #variable {MSDP_%0} {%1}
}

#EVENT {IAC SB MSDP ROOM}
{
    #variable {MSDP_ROOM} {%1};
    #map goto {$MSDP_ROOM[VNUM]} {dig};
    #map set roomarea $MSDP_ROOM[AREA];
    #map set roomname $MSDP_ROOM[NAME];
    #map set roomterrain $MSDP_ROOM[TERRAIN];
    #map set roomcolor <178>;
    #nop Create unmapped exits and color unexplored rooms red.;
    #foreach {*MSDP_ROOM[EXITS][]} {EXIT}
    {
        #map get {roomexit} {EXIT_LIST};
        #if {&EXIT_LIST[$EXIT] == 0}
        {
            #map get {roomvnum} {EXIT_VNUM} {$MSDP_ROOM[EXITS][$EXIT]};
            #map dig {$EXIT} {$MSDP_ROOM[EXITS][$EXIT]};
            #if {$EXIT_VNUM == 0}
            {
                #map set {roomcolor} {<118>} {$MSDP_ROOM[EXITS][$EXIT]}
            }
        }
    }
}

#ALIAS {msdp_report}
{
    #nop Ask the server to report all keys inside REPORTABLE_VARIABLES;
    #line msdp #send {REPORT}{$REPORTABLE_VARIABLES}\
}

#ALIAS {msdp_list}
{
    #line msdp #send {LIST}{%0}\
}

#ALIAS {msdp_send}
{
    #line msdp #send {SEND}{%0}\
}

#ALIAS {example}
{
    msdp_list COMMANDS;
    msdp_list REPORTABLE_VARIABLES;
    msdp_report
}