TinTin++ Mud Client Scripts  
space
space
The following script, tested on realms of despair, tries to capture the text of a description and edit it in the editor named 'joe'. Replacing joe with your own favorite editor should be enough to get it working. Useful for olc and writing notes. Might work for other codebases as well with some adjustments.

This script is written for v2.01.97 and higher

space
#VARIABLE {copydesc} {0}

#ACTION {^Begin entering your text now}
{
     #config log raw;
     #variable copydesc 1;
     #send {/l}
}

#ACTION {%1| %2}
{
     #if {$copydesc == 2}
     {
          #if {"%2" != ""}
          {
               #line logverbatim tmp.txt %2
          };
          #else
          {
               #line logverbatim tmp.txt { }
          }
     }
}
{9}

#ACTION {^------------------$}
{
     #if {$copydesc == 2}
     {
          #variable copydesc 0;
          #nop Replace 'joe' with your favorite editor.;
          #system joe tmp.txt;
          #send {/c};
          #textin tmp.txt;
          #system rm tmp.txt;
          #send {/l}
     };
     #if {$copydesc == 1}
     {
          #variable copydesc 2
     }
}

#ACTION {^Buffer is empty.}
{
     #if {$copydesc == 1}
     {
          #variable copydesc 0;
          #system joe tmp.txt;
          #textin tmp.txt;
          #system rm tmp.txt
     }
}